Tutorial de Arduino y de radiofrecuencia con VirtualWire

Posted on February 10, 2015 by N4n0

¡Hola! Hoy voy a explicaros cómo conectar dos placas Arduino de forma inalámbrica con un módulo de radiofrecuencia RF 433MHZ.

Emisor (izquierda) y receptor(derecha)

Estos módulos vienen en parejas: un receptor y un emisor que se comunican mediante ondas de radio. No son ninguna maravilla, pero permiten comunicar dos dispositivos… ¡por poco dinero! Cuestan entre 2 y 5 euros el par.

Cómo programar estos chismes desde cero es muy laborioso, podemos utilizar la librería VirtualWire. Esta librería se encarga de gestionar las funciones más básicas de estos módulos de radiofrecuencia low-cost: envío de información, comprobación de los paquetes de datos…
Os recomiendo que descarguéis la librería desde este enlace. Los que no sepáis cómo instalar librerías en Linux, seguid nuestro tutorial.

Para probar los módulos de radiofrecuencia, haremos que una de las placas Arduino dé la orden a la otra para que encienda el LED del pin 13.

Componentes

¿Qué necesitamos?

2x Placas Arduino: UNO, Duemilanove, Nano o Mega servirán
Receptor y emisor de radiofrecuencia: recomiendo soldar una antena al emisor
Batería/Pilas: alimentaremos una placa con el cable USB y la otra con pilas
Breadboard y jumpers
Cable USB de impresora

Y ya está. Hoy sale barato 🙂

Conexiones

Las conexiones de cada una de las placas Arduino con los módulos serán:

Emisor:
-Arduino 5V – Módulo VCC
-Arduino GND – Módulo GND
-Arduino Digital 12 – Módulo DATA

Emisor

Receptor:
-Arduino 5V – Módulo VCC
-Arduino GND – Módulo GND
-Arduino Digital 11 – Módulo DATA (tiene dos pines DATA: cualquiera de los dos vale)
-Arduino VCC – Positivo de la batería
-Arduino GND – Negativo de la batería

Receptor

Código del Receptor

Arduino recibirá un mensaje que se guardará en el array de carácteres message[]. Después, comprobará que este mensaje se corresponda a la instrucción “Encender” o “Apagar”, y si es así encenderá o apagará el LED 13.


/*
RECEPTOR

Apaga el LED 13 si recibe el mensaje "Apagar"
Enciende el LED 13 si recibe el mensaje "Encender"

Escrito por Nano en beneficio de los seres humanos
www.robologs.net
*/

#include <VirtualWire.h>

//Creamos un mensaje
//La constante VW_MAX_MESSAGE_LEN viene definida en la libreria
byte message[VW_MAX_MESSAGE_LEN];
byte messageLength = VW_MAX_MESSAGE_LEN;

void setup()
{
  pinMode(13, OUTPUT); //Configuramos el pin 13
 
  Serial.begin(9600);//Iniciamos el Serial
  Serial.println("Iniciando...");
 
  vw_setup(2000);
  vw_rx_start();
}
void loop()
{
  if (vw_get_message(message, &messageLength))
  {
      if(comparar("Encender") == 0){
        digitalWrite(13, HIGH);
        Serial.write("LED Encendido\n");
      }
      else if(comparar("Apagar") == 0)
      {
        digitalWrite(13,LOW);
        Serial.write("LED Apagado\n");
      }
 
  }
}

char comparar(char* cadena) {
  //Esta funcion compara el string cadena con el mensaje recibido.
  //Si son iguales, devuelve 1. Si no, devuelve 0.
 
  for(int i = 0; i<messageLength; i++)
  {
    if(message[i] != cadena[i])
    {
      return 1;
    }
  }

    return 0;
}

En el programa usamos funciones propias de VirtualWire.

vw_setup_(2000) sirve para iniciar la comunicación por radio, de forma similar al Serial.begin().
vw_rx_start() inicia el pin de recepción. Si no le decimos nada, el pin por defecto es el 11. Si quisiéramos cambiarlo al 9 (por ejemplo), deberíamos escribir vw_set_rx_pin(9) antes de iniciarlo.
vw_get_message() lee un mensaje de longitud messageLength y lo guarda en el array message. Además devuelve true si el mensaje está correcto o false si está corrupto. De ahí que en el código lo pongamos dentro de un condicional. Lo que estamos diciendo es: “Lee el mensaje. Si no está corrupto, continúa”

Código del Emisor

El emisor emite los mensajes “Encender” y “Apagar” en intervalos de un segundo.

/*
EMISOR

Envia los mensajes "Apagar" y "Encender" en intervalos de un segundo

Escrito por Nano en beneficio de los seres humanos
www.robologs.net
*/

#include <VirtualWire.h>

void setup()
{
  //Iniciamos el Serial y la comunicacion por radio
  Serial.begin(9600);
  Serial.write("Sistema encendido\n");
  vw_setup(2000);
}
void loop()
{
  send("Encender");
  delay(1000);
  send("Apagar");
  delay(1000);
}

//Funcion para enviar el mensaje
void send (char *message)
{
  vw_send((uint8_t *)message, strlen(message)); //Envia el mensaje
  vw_wait_tx(); //Espera hasta que se haya acabado de transmitir todo
 
  Serial.println(message); //Muestra el mensaje por Serial
}

vw_send() sirve para enviar el mensaje. Recibe dos parámetros: el primero es la función en sí y el segundo cuántos bytes contiene el mensaje.
vw_wait_tx() espera hasta que se haya transmitido todo el mensaje antes de continuar con el programa.

Escribimos una función send() para que sea más cómodo enviar los mensajes. Así no tenemos que escribir cada vez vw_send() y vw_wait_tx().

Si quisiéramos cambiar el pin de recepción, deberíamos escribir vw_set_rx_pin(numero_pin) justo antes de vw_setup(2000). Si no decimos nada, por defecto será el 11. Si queremos cambiar el pin tx, podemos hacerlo con vw_set_tx_pin(numero_pin).

¡Y ya está! Bueno, ¿Qué tal ha salido? Si habéis seguido mis pasos, veréis cómo el LED 13 del receptor se enciende y se apaga. Si no es así… ¡volved a repasar todos los pasos!

Si tenéis alguna duda, comentario, etc, podéis escribirme en los comentarios de abajo. 🙂

Actualización 11 de Mayo de 2016:

Leyendo los comentarios, veo que una de las consultas que más gente me hace es cómo enviar la señal de “encender” pulsando un botón o con un sensor de distancia infrarrojo, en vez de hacerlo automáticamente.

Venga, gente, ¿no me digáis que no sabéis hacerlo? ¡Si es muy fácil! 😛

Sólo hay que añadir un condicional “if” que mire si se cumple la condición de encendido. En el caso del botón, el void loop quedaría:


void loop()
{
  if(digitalRead(boton) == HIGH)
  {
      send("Encender");
  }
  else
  {
    send("Apagar");
  }
  delay(100);
}

Con el botón es más de lo mismo. Si tenemos una función que devuelve la distancia del sensor (que llamaremos leer_sensor()), sólo hay que poner un condicional:


void loop()
{
  if(leer_sensor() >= 100) //Sustutuimos 100 por cualquier distancia
  {
      send("Encender");
  }
  else
  {
    send("Apagar");
  }
  delay(100);
}

La única “dificultad” será construirnos esta función leer_sensor(), aunque muchos fabricantes de sensores ofrecen ejemplos de cómo utilizar su sensor con Arduino.

N4n0

Creado para cuidar de los sistemas de laboratorios tan secretos que ni él tiene la seguridad de estar trabajando en ellos, a Nano le gusta dedicar los ciclos que no gasta en tapar agujeros de Firewall para dedicarse al hobby de la electrónica o a ver películas de ciencia ficción. Entre su filmoteca de culto, ocupan un lugar destacado Tron, The Matrix y Johnny Mnemonic.

más nuevos primero más antiguos primero

Humano

Aldebaran_33

Hola mundo! Gracias por el post, por brindar tu apoyo a la comunidad de desarroladores en general. Mi consulta es la siguiente: Estoy utilizando dos arduinos (Emisor y receptor). Quiero implementarlo ahora con un arduino(emisor) y la raspeberry pi 3(receptor). Por ejemplo estoy enviando un entero (533) desde el emisor hacia el receptor. Como leeria ese valor en la Raspberry ? Ademas para eso tengo que saber la naturaleza de este modulo. Por eso quiero saber como recibe la informacion el receptor? He estado averiguando un poco, menciona que es una tranmision Simplex (unidireccional), pero de ahí nada más. Agradeceria… Leer más »

Humano

mariano

hola que tal, tengo una duda. estoy haciendo un coche de control remoto con pulsadores, pero tengo una duda con los botones debido a que no se como ponerlo en el receptor. no se si puedas ayudarme con el código por favor.

Autor